1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
|
-module(telnet_server).
-compile(export_all).
%% telnet control characters
-define(SE, 240).
-define(NOP, 241).
-define(DM, 242).
-define(BRK, 243).
-define(IP, 244).
-define(AO, 245).
-define(AYT, 246).
-define(EC, 247).
-define(EL, 248).
-define(GA, 249).
-define(SB, 250).
-define(WILL, 251).
-define(WONT, 252).
-define(DO, 253).
-define(DONT, 254).
-define(IAC, 255).
%% telnet options
-define(BINARY, 0).
-define(ECHO, 1).
-define(SUPPRESS_GO_AHEAD, 3).
-define(TERMINAL_TYPE, 24).
-record(state,
{listen,
client,
users,
authorized=false,
suppress_go_ahead=false,
buffer=[]}).
-type options() :: [{port,pos_integer()} | {users,users()}].
-type users() :: [{user(),password()}].
-type user() :: string().
-type password() :: string().
-spec start(Opts::options()) -> Pid::pid().
start(Opts) when is_list(Opts) ->
spawn_link(fun() -> init(Opts) end).
-spec stop(Pid::pid()) -> ok.
stop(Pid) ->
Ref = erlang:monitor(process,Pid),
Pid ! stop,
receive {'DOWN',Ref,_,_,_} -> ok end.
init(Opts) ->
Port = proplists:get_value(port,Opts),
Users = proplists:get_value(users,Opts,[]),
{ok, LSock} = gen_tcp:listen(Port, [list, {packet, 0},
{active, true}]),
State = #state{listen=LSock,users=Users},
accept(State),
ok = gen_tcp:close(LSock).
accept(#state{listen=LSock}=State) ->
Server = self(),
Acceptor = spawn_link(fun() -> do_accept(LSock,Server) end),
receive
{Acceptor,Sock} when is_port(Sock) ->
case init_client(State#state{client=Sock}) of
stopped ->
io:format("[telnet_server] telnet_server stopped\n"),
ok;
R ->
io:format("[telnet_server] connection to client "
"closed with reason ~p~n",[R]),
accept(State)
end;
{Acceptor,closed} ->
io:format("[telnet_server] listen socket closed unexpectedly, "
"terminating telnet_server\n"),
ok;
stop ->
io:format("[telnet_server] telnet_server stopped\n"),
ok
end.
do_accept(LSock,Server) ->
case gen_tcp:accept(LSock) of
{ok, Sock} ->
ok = gen_tcp:controlling_process(Sock,Server),
Server ! {self(),Sock};
{error,closed} ->
%% This will happen when stop/1 is called, since listen
%% socket is closed. Then the server is probably already
%% dead by now, but to be 100% sure not to hang, we send a
%% message to say what happened.
Server ! {self(),closed}
end.
init_client(#state{client=Sock}=State) ->
dbg("Server sending: ~p~n",["login: "]),
R = case gen_tcp:send(Sock,"login: ") of
ok ->
loop(State, 1);
Error ->
Error
end,
_ = gen_tcp:close(Sock),
R.
loop(State, N) ->
receive
{tcp,_,Data} ->
try handle_data(Data,State) of
{ok,State1} ->
loop(State1, N)
catch
throw:Error ->
Error
end;
{tcp_closed, _} ->
closed;
{tcp_error,_,Error} ->
{error,tcp,Error};
stop ->
stopped
after
500 ->
Report = lists:flatten(
io_lib:format("The CT Telnet Server says: "
"Iteration no ~w\r\n", [N])),
dbg("Server sending: ~s~n", [Report]),
gen_tcp:send(State#state.client, Report),
loop(State, N+1)
end.
handle_data([?IAC|Cmd],State) ->
dbg("Server got cmd: ~p~n",[Cmd]),
handle_cmd(Cmd,State);
handle_data(Data,State) ->
dbg("Server got data: ~p~n",[Data]),
case get_line(Data,[]) of
{Line,Rest} ->
WholeLine = lists:flatten(lists:reverse(State#state.buffer,Line)),
{ok,State1} = do_handle_data(WholeLine,State),
case Rest of
[] -> {ok,State1};
_ -> handle_data(Rest,State1)
end;
false ->
{ok,State#state{buffer=[Data|State#state.buffer]}}
end.
%% Add function clause below to handle new telnet commands (sent with
%% ?IAC from client - this is not possible to do from ct_telnet API,
%% but ct_telnet sends DONT SUPPRESS_GO_AHEAD)
handle_cmd([?DO,?SUPPRESS_GO_AHEAD|T],State) ->
send([?IAC,?WILL,?SUPPRESS_GO_AHEAD],State),
handle_cmd(T,State#state{suppress_go_ahead=true});
handle_cmd([?DONT,?SUPPRESS_GO_AHEAD|T],State) ->
send([?IAC,?WONT,?SUPPRESS_GO_AHEAD],State),
handle_cmd(T,State#state{suppress_go_ahead=false});
handle_cmd([?IAC|T],State) ->
%% Multiple commands in one packet
handle_cmd(T,State);
handle_cmd([_H|T],State) ->
%% Not responding to this command
handle_cmd(T,State);
handle_cmd([],State) ->
{ok,State}.
%% Add function clause below to handle new text command (text entered
%% from the telnet prompt)
do_handle_data(Data,#state{authorized=false}=State) ->
check_user(Data,State);
do_handle_data(Data,#state{authorized={user,_}}=State) ->
check_pwd(Data,State);
do_handle_data("echo "++ Data,State) ->
send(Data++"\r\n> ",State),
{ok,State};
do_handle_data("echo_no_prompt "++ Data,State) ->
send(Data,State),
{ok,State};
do_handle_data("echo_ml "++ Data,State) ->
Lines = string:tokens(Data," "),
ReturnData = string:join(Lines,"\n"),
send(ReturnData++"\r\n> ",State),
{ok,State};
do_handle_data("echo_ml_no_prompt "++ Data,State) ->
Lines = string:tokens(Data," "),
ReturnData = string:join(Lines,"\n"),
send(ReturnData,State),
{ok,State};
do_handle_data([],State) ->
send("> ",State),
{ok,State};
do_handle_data(_Data,State) ->
send("error: unknown command\r\n> ",State),
{ok,State}.
check_user(User,State) ->
case lists:keyfind(User,1,State#state.users) of
{User,Pwd} ->
dbg("user ok\n"),
send("Password: ",State),
{ok,State#state{authorized={user,Pwd}}};
false ->
throw({error,unknown_user})
end.
check_pwd(Pwd,#state{authorized={user,Pwd}}=State) ->
dbg("password ok\n"),
send("Welcome to the ultimate telnet server!\r\n> ",State),
{ok,State#state{authorized=true}};
check_pwd(_,_State) ->
throw({error,authentication}).
send(Data,State) ->
dbg("Server sending: ~p~n",[Data]),
case gen_tcp:send(State#state.client,Data) of
ok ->
ok;
{error,Error} ->
throw({error,send,Error})
end.
get_line([$\r,$\n|Rest],Acc) ->
{lists:reverse(Acc),Rest};
get_line([$\r,0|Rest],Acc) ->
{lists:reverse(Acc),Rest};
get_line([$\n|Rest],Acc) ->
{lists:reverse(Acc),Rest};
get_line([H|T],Acc) ->
get_line(T,[H|Acc]);
get_line([],_) ->
false.
dbg(_F) ->
dbg(_F,[]).
dbg(_F,_A) ->
io:format("[telnet_server] "++_F,_A).
|
