1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
|
%%
%% %CopyrightBegin%
%%
%% Copyright Ericsson AB 1997-2011. All Rights Reserved.
%%
%% The contents of this file are subject to the Erlang Public License,
%% Version 1.1, (the "License"); you may not use this file except in
%% compliance with the License. You should have received a copy of the
%% Erlang Public License along with this software. If not, it can be
%% retrieved online at http://www.erlang.org/.
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
%% the License for the specific language governing rights and limitations
%% under the License.
%%
%% %CopyrightEnd%
%%
-module(inet_tcp).
%% Socket server for TCP/IP
-export([connect/3, connect/4, listen/2, accept/1, accept/2, close/1]).
-export([send/2, send/3, recv/2, recv/3, unrecv/2]).
-export([shutdown/2]).
-export([controlling_process/2]).
-export([fdopen/2]).
-export([family/0, mask/2, parse_address/1]).
-export([getserv/1, getaddr/1, getaddr/2, getaddrs/1, getaddrs/2]).
-include("inet_int.hrl").
%% my address family
family() -> inet.
%% Apply netmask on address
mask({M1,M2,M3,M4}, {IP1,IP2,IP3,IP4}) ->
{M1 band IP1,
M2 band IP2,
M3 band IP3,
M4 band IP4}.
%% Parse address string
parse_address(Host) ->
inet_parse:ipv4strict_address(Host).
%% inet_tcp port lookup
getserv(Port) when is_integer(Port) -> {ok, Port};
getserv(Name) when is_atom(Name) -> inet:getservbyname(Name,tcp).
%% inet_tcp address lookup
getaddr(Address) -> inet:getaddr(Address, inet).
getaddr(Address,Timer) -> inet:getaddr_tm(Address, inet, Timer).
%% inet_tcp address lookup
getaddrs(Address) -> inet:getaddrs(Address, inet).
getaddrs(Address,Timer) -> inet:getaddrs_tm(Address,inet,Timer).
%%
%% Send data on a socket
%%
send(Socket, Packet, Opts) -> prim_inet:send(Socket, Packet, Opts).
send(Socket, Packet) -> prim_inet:send(Socket, Packet, []).
%%
%% Receive data from a socket (inactive only)
%%
recv(Socket, Length) -> prim_inet:recv(Socket, Length).
recv(Socket, Length, Timeout) -> prim_inet:recv(Socket, Length, Timeout).
unrecv(Socket, Data) -> prim_inet:unrecv(Socket, Data).
%%
%% Shutdown one end of a socket
%%
shutdown(Socket, How) ->
prim_inet:shutdown(Socket, How).
%%
%% Close a socket (async)
%%
close(Socket) ->
inet:tcp_close(Socket).
%%
%% Set controlling process
%%
controlling_process(Socket, NewOwner) ->
inet:tcp_controlling_process(Socket, NewOwner).
%%
%% Connect
%%
connect(Address, Port, Opts) ->
do_connect(Address, Port, Opts, infinity).
connect(Address, Port, Opts, infinity) ->
do_connect(Address, Port, Opts, infinity);
connect(Address, Port, Opts, Timeout) when is_integer(Timeout),
Timeout >= 0 ->
do_connect(Address, Port, Opts, Timeout).
do_connect({A,B,C,D}, Port, Opts, Time) when ?ip(A,B,C,D), ?port(Port) ->
case inet:connect_options(Opts, inet) of
{error, Reason} -> exit(Reason);
{ok, #connect_opts{fd=Fd,
ifaddr=BAddr={Ab,Bb,Cb,Db},
port=BPort,
opts=SockOpts}}
when ?ip(Ab,Bb,Cb,Db), ?port(BPort) ->
case inet:open(Fd,BAddr,BPort,SockOpts,tcp,inet,stream,?MODULE) of
{ok, S} ->
case prim_inet:connect(S, {A,B,C,D}, Port, Time) of
ok -> {ok,S};
Error -> prim_inet:close(S), Error
end;
Error -> Error
end;
{ok, _} -> exit(badarg)
end.
%%
%% Listen
%%
listen(Port, Opts) ->
case inet:listen_options([{port,Port} | Opts], inet) of
{error,Reason} -> exit(Reason);
{ok, #listen_opts{fd=Fd,
ifaddr=BAddr={A,B,C,D},
port=BPort,
opts=SockOpts}=R}
when ?ip(A,B,C,D), ?port(BPort) ->
case inet:open(Fd,BAddr,BPort,SockOpts,tcp,inet,stream,?MODULE) of
{ok, S} ->
case prim_inet:listen(S, R#listen_opts.backlog) of
ok -> {ok, S};
Error -> prim_inet:close(S), Error
end;
Error -> Error
end;
{ok, _} -> exit(badarg)
end.
%%
%% Accept
%%
accept(L) ->
case prim_inet:accept(L) of
{ok, S} ->
inet_db:register_socket(S, ?MODULE),
{ok,S};
Error -> Error
end.
accept(L,Timeout) ->
case prim_inet:accept(L,Timeout) of
{ok, S} ->
inet_db:register_socket(S, ?MODULE),
{ok,S};
Error -> Error
end.
%%
%% Create a port/socket from a file descriptor
%%
fdopen(Fd, Opts) ->
inet:fdopen(Fd, Opts, tcp, inet, stream, ?MODULE).
|
