4 files changed, 129 insertions, 0 deletions
diff --git a/examples/tcp_reverse/src/reverse_protocol.erl b/examples/tcp_reverse/src/reverse_protocol.erl
new file mode 100644
index 0000000..6f7c770
--- /dev/null
+++ b/examples/tcp_reverse/src/reverse_protocol.erl
@@ -0,0 +1,73 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(reverse_protocol).
+-behaviour(gen_server).
+-behaviour(ranch_protocol).
+
+%% API.
+-export([start_link/4]).
+
+%% gen_server.
+-export([init/1]).
+-export([init/4]).
+-export([handle_call/3]).
+-export([handle_cast/2]).
+-export([handle_info/2]).
+-export([terminate/2]).
+-export([code_change/3]).
+
+-define(TIMEOUT, 5000).
+
+-record(state, {socket, transport}).
+
+%% API.
+
+start_link(Ref, Socket, Transport, Opts) ->
+	proc_lib:start_link(?MODULE, init, [Ref, Socket, Transport, Opts]).
+
+%% gen_server.
+
+%% This function is never called. We only define it so that
+%% we can use the -behaviour(gen_server) attribute.
+init([]) -> {ok, undefined}.
+
+init(Ref, Socket, Transport, _Opts = []) ->
+	ok = proc_lib:init_ack({ok, self()}),
+	ok = ranch:accept_ack(Ref),
+	ok = Transport:setopts(Socket, [{active, once}]),
+	gen_server:enter_loop(?MODULE, [],
+		#state{socket=Socket, transport=Transport},
+		?TIMEOUT).
+
+handle_info({tcp, Socket, Data}, State=#state{
+		socket=Socket, transport=Transport}) ->
+	Transport:setopts(Socket, [{active, once}]),
+	Transport:send(Socket, reverse_binary(Data)),
+	{noreply, State, ?TIMEOUT};
+handle_info({tcp_closed, _Socket}, State) ->
+	{stop, normal, State};
+handle_info({tcp_error, _, Reason}, State) ->
+	{stop, Reason, State};
+handle_info(timeout, State) ->
+	{stop, normal, State};
+handle_info(_Info, State) ->
+	{stop, normal, State}.
+
+handle_call(_Request, _From, State) ->
+	{reply, ok, State}.
+
+handle_cast(_Msg, State) ->
+	{noreply, State}.
+
+terminate(_Reason, _State) ->
+	ok.
+
+code_change(_OldVsn, State, _Extra) ->
+	{ok, State}.
+
+%% Internal.
+
+reverse_binary(B) when is_binary(B) ->
+	[list_to_binary(lists:reverse(binary_to_list(
+		binary:part(B, {0, byte_size(B)-2})
+	))), "\r\n"].
diff --git a/examples/tcp_reverse/src/tcp_reverse.app.src b/examples/tcp_reverse/src/tcp_reverse.app.src
new file mode 100644
index 0000000..46cfca7
--- /dev/null
+++ b/examples/tcp_reverse/src/tcp_reverse.app.src
@@ -0,0 +1,15 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+{application, tcp_reverse, [
+	{description, "Ranch TCP reverse example."},
+	{vsn, "1"},
+	{modules, []},
+	{registered, [tcp_reverse_sup]},
+	{applications, [
+		kernel,
+		stdlib,
+		ranch
+	]},
+	{mod, {tcp_reverse_app, []}},
+	{env, []}
+]}.
diff --git a/examples/tcp_reverse/src/tcp_reverse_app.erl b/examples/tcp_reverse/src/tcp_reverse_app.erl
new file mode 100644
index 0000000..106e527
--- /dev/null
+++ b/examples/tcp_reverse/src/tcp_reverse_app.erl
@@ -0,0 +1,19 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(tcp_reverse_app).
+-behaviour(application).
+
+%% API.
+-export([start/2]).
+-export([stop/1]).
+
+%% API.
+
+start(_Type, _Args) ->
+    {ok, _} = ranch:start_listener(tcp_reverse, 10,
+		ranch_tcp, [{port, 5555}], reverse_protocol, []),
+    tcp_reverse_sup:start_link().
+
+stop(_State) ->
+	ok.
diff --git a/examples/tcp_reverse/src/tcp_reverse_sup.erl b/examples/tcp_reverse/src/tcp_reverse_sup.erl
new file mode 100644
index 0000000..4264d18
--- /dev/null
+++ b/examples/tcp_reverse/src/tcp_reverse_sup.erl
@@ -0,0 +1,22 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(tcp_reverse_sup).
+-behaviour(supervisor).
+
+%% API.
+-export([start_link/0]).
+
+%% supervisor.
+-export([init/1]).
+
+%% API.
+
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+    supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+%% supervisor.
+
+init([]) ->
+	{ok, {{one_for_one, 10, 10}, []}}.