Merge branch 'rickard/time_api/OTP-11997'

* rickard/time_api/OTP-11997: (22 commits)
  Update primary bootstrap
  inets: Suppress deprecated warning on erlang:now/0
  inets: Cleanup of multiple copies of functions Add inets_lib with common functions used by multiple modules
  inets: Update comments
  Suppress deprecated warning on erlang:now/0
  Use new time API and be back-compatible in inets Remove unused functions and removed redundant test
  asn1 test SUITE: Eliminate use of now/0
  Disable deprecated warning on erlang:now/0 in diameter_lib
  Use new time API and be back-compatible in ssh
  Replace all calls to now/0 in CT with new time API functions
  test_server: Replace usage of erlang:now() with usage of new API
  Replace usage of erlang:now() with usage of new API
  Replace usage of erlang:now() with usage of new API
  Replace usage of erlang:now() with usage of new API
  Replace usage of erlang:now() with usage of new API
  otp_SUITE: Warn for calls to erlang:now/0
  Replace usage of erlang:now() with usage of new API
  Multiple timer wheels
  Erlang based BIF timer implementation for scalability
  Implement ethread events with timeout
  ...

Conflicts:
	bootstrap/bin/start.boot
	bootstrap/bin/start_clean.boot
	bootstrap/lib/compiler/ebin/beam_asm.beam
	bootstrap/lib/compiler/ebin/compile.beam
	bootstrap/lib/kernel/ebin/auth.beam
	bootstrap/lib/kernel/ebin/dist_util.beam
	bootstrap/lib/kernel/ebin/global.beam
	bootstrap/lib/kernel/ebin/hipe_unified_loader.beam
	bootstrap/lib/kernel/ebin/inet_db.beam
	bootstrap/lib/kernel/ebin/inet_dns.beam
	bootstrap/lib/kernel/ebin/inet_res.beam
	bootstrap/lib/kernel/ebin/os.beam
	bootstrap/lib/kernel/ebin/pg2.beam
	bootstrap/lib/stdlib/ebin/dets.beam
	bootstrap/lib/stdlib/ebin/dets_utils.beam
	bootstrap/lib/stdlib/ebin/erl_tar.beam
	bootstrap/lib/stdlib/ebin/escript.beam
	bootstrap/lib/stdlib/ebin/file_sorter.beam
	bootstrap/lib/stdlib/ebin/otp_internal.beam
	bootstrap/lib/stdlib/ebin/qlc.beam
	bootstrap/lib/stdlib/ebin/random.beam
	bootstrap/lib/stdlib/ebin/supervisor.beam
	bootstrap/lib/stdlib/ebin/timer.beam
	erts/aclocal.m4
	erts/emulator/beam/bif.c
	erts/emulator/beam/erl_bif_info.c
	erts/emulator/beam/erl_db_hash.c
	erts/emulator/beam/erl_init.c
	erts/emulator/beam/erl_process.h
	erts/emulator/beam/erl_thr_progress.c
	erts/emulator/beam/utils.c
	erts/emulator/sys/unix/sys.c
	erts/preloaded/ebin/erlang.beam
	erts/preloaded/ebin/erts_internal.beam
	erts/preloaded/ebin/init.beam
	erts/preloaded/src/erts_internal.erl
	lib/common_test/test/ct_hooks_SUITE_data/cth/tests/empty_cth.erl
	lib/diameter/src/base/diameter_lib.erl
	lib/kernel/src/os.erl
	lib/ssh/test/ssh_basic_SUITE.erl
	system/doc/efficiency_guide/advanced.xml

1 files changed, 281 insertions, 0 deletions

diff --git a/erts/preloaded/src/erts_internal.erl b/erts/preloaded/src/erts_internal.erl
index 5756d80424..e2c3d40f61 100644
--- a/erts/preloaded/src/erts_internal.erl
+++ b/erts/preloaded/src/erts_internal.erl
@@ -38,6 +38,18 @@
 
 -export([check_process_code/2]).
 
+-export([flush_monitor_messages/3]).
+
+-export([time_unit/0]).
+
+-export([bif_timer_server/2]).
+
+-export([get_bif_timer_servers/0, create_bif_timer/0, access_bif_timer/1]).
+
+-export([monitor_process/2]).
+
+-export([is_system_process/1]).
+
 %%
 %% Await result of send to port
 %%
@@ -195,3 +207,272 @@ map_type(_M) ->
 
 map_hashmap_children(_M) ->
     erlang:nif_error(undefined).
+
+-spec erts_internal:flush_monitor_messages(Ref, Multi, Res) -> term() when
+      Ref :: reference(),
+      Multi :: boolean(),
+      Res :: term().
+
+%% erlang:demonitor(Ref, [flush]) traps to
+%% erts_internal:flush_monitor_messages(Ref, Res) when
+%% it needs to flush monitor messages.
+flush_monitor_messages(Ref, Multi, Res) when is_reference(Ref) ->
+    receive
+	{_, Ref, _, _, _} ->
+	    case Multi of
+		false ->
+		    Res;
+		_ ->
+		    flush_monitor_messages(Ref, Multi, Res)
+	    end
+    after 0 ->
+	    Res
+    end.
+
+-spec erts_internal:time_unit() -> pos_integer().
+
+time_unit() ->
+    erlang:nif_error(undefined).
+
+-spec erts_internal:get_bif_timer_servers() -> Pids when
+      Pid :: pid(),
+      Pids :: [Pid].
+
+get_bif_timer_servers() ->
+    erlang:nif_error(undefined).
+
+-spec erts_internal:create_bif_timer() -> Res when
+      Res :: {reference(), pid(), reference()}.
+
+create_bif_timer() ->
+    erlang:nif_error(undefined).
+
+-spec erts_internal:access_bif_timer(Ref) -> Res when
+      Ref :: reference(),
+      Res :: {reference(), pid(), reference()}.
+
+access_bif_timer(_Ref) ->
+    erlang:nif_error(undefined).
+
+-spec erts_internal:monitor_process(Pid, Ref) -> boolean() when
+      Pid :: pid(),
+      Ref :: reference().
+
+monitor_process(_Pid, _Ref) ->
+    erlang:nif_error(undefined).
+
+-spec erts_internal:is_system_process(Pid) -> boolean() when
+      Pid :: pid().
+
+is_system_process(_Pid) ->
+    erlang:nif_error(undefined).
+
+%%
+%% BIF timer servers
+%%
+
+-record(tsrv_state, {rtab,
+		     ttab,
+		     btr,
+		     unit,
+		     next}).
+
+bif_timer_server(N, BTR) ->
+    try
+	tsrv_loop(tsrv_init_static_state(N, BTR), infinity)
+    catch
+	Type:Reason ->
+	    erlang:display({'BIF_timer_server',
+			    {Type, Reason},
+			    erlang:get_stacktrace()}),
+	    exit(Reason)
+    end.
+
+tsrv_init_static_state(N, BTR) ->
+    process_flag(trap_exit, true),
+    NList = integer_to_list(N),
+    RTabName = list_to_atom("BIF_timer_reference_table_" ++ NList),
+    TTabName = list_to_atom("BIF_timer_time_table_" ++ NList),
+    #tsrv_state{rtab = ets:new(RTabName,
+			       [set, private, {keypos, 2}]),
+		ttab = ets:new(TTabName,
+			       [ordered_set, private, {keypos, 1}]),
+		btr = BTR,
+		unit = erts_internal:time_unit(),
+		next = infinity}.
+    
+
+tsrv_loop(#tsrv_state{unit = Unit} = StaticState, Nxt) ->
+    CallTime = erlang:monotonic_time(),
+    %% 'infinity' is greater than all integers...
+    NewNxt = case CallTime >= Nxt of
+		 true ->
+		     tsrv_handle_timeout(CallTime, StaticState);
+		 false ->
+		     TMO = try
+			       (1000*(Nxt - CallTime - 1)) div Unit + 1
+			   catch
+			       error:badarith when Nxt == infinity -> infinity
+			   end,
+		     receive
+			 Msg ->
+			     tsrv_handle_msg(Msg, StaticState, Nxt)
+		     after TMO ->
+			     Nxt
+		     end
+	     end,
+    tsrv_loop(StaticState, NewNxt).
+
+tsrv_handle_msg({set_timeout, BTR, Proc, Time, TRef, Msg},
+		#tsrv_state{rtab = RTab,
+			    ttab = TTab,
+			    btr = BTR},
+		Nxt) when erlang:is_integer(Time) ->
+    RcvTime = erlang:monotonic_time(),
+    case Time =< RcvTime of
+	true ->
+	    try Proc ! Msg catch _:_ -> ok end,
+	    Nxt;
+	false ->
+	    Ins = case erlang:is_atom(Proc) of
+		      true ->
+			  true;
+		      false ->
+			  try
+			      erts_internal:monitor_process(Proc, TRef)
+			  catch
+			      _:_ -> false
+			  end
+		  end,
+	    case Ins of
+		false ->
+		    Nxt;
+		true ->
+		    TKey = {Time, TRef},
+		    true = ets:insert(RTab, TKey),
+		    true = ets:insert(TTab, {TKey, Proc, Msg}),
+		    case Time < Nxt of
+			true -> Time;
+			false -> Nxt
+		    end
+	    end
+    end;
+tsrv_handle_msg({cancel_timeout, BTR, From, Reply, Req, TRef},
+		#tsrv_state{rtab = RTab,
+			    ttab = TTab,
+			    unit = Unit,
+			    btr = BTR},
+		Nxt) ->
+    case ets:lookup(RTab, TRef) of
+	[] ->
+	    case Reply of
+		false ->
+		    ok;
+		_ ->
+		    try From ! {cancel_timer, Req, false} catch _:_ -> ok end
+	    end,
+	    Nxt;
+	[{Time, TRef} = TKey] ->
+	    ets:delete(RTab, TRef),
+	    ets:delete(TTab, TKey),
+	    erlang:demonitor(TRef),
+	    case Reply of
+		false ->
+		    ok;
+		_ ->
+		    RcvTime = erlang:monotonic_time(),
+		    RT = case Time =< RcvTime of
+			     true ->
+				 0;
+			     false ->
+				 ((1000*(Time - RcvTime)) div Unit)
+			 end,
+		    try From ! {cancel_timer, Req, RT} catch _:_ -> ok end
+	    end,
+	    case Time =:= Nxt of
+		false ->
+		    Nxt;
+		true ->
+		    case ets:first(TTab) of
+			'$end_of_table' -> infinity;
+			{NextTime, _TRef} -> NextTime
+		    end
+	    end
+    end;
+tsrv_handle_msg({read_timeout, BTR, From, Req, TRef},
+		#tsrv_state{rtab = RTab,
+			    unit = Unit,
+			    btr = BTR},
+		Nxt) ->
+    case ets:lookup(RTab, TRef) of
+	[] ->
+	    try From ! {read_timer, Req, false} catch _:_ -> ok end;
+	[{Time, TRef}] ->
+	    RcvTime = erlang:monotonic_time(),
+	    RT = case Time =< RcvTime of
+		     true -> 0;
+		     false -> (1000*(Time - RcvTime)) div Unit
+		 end,
+	    try From ! {read_timer, Req, RT} catch _:_ -> ok end
+    end,
+    Nxt;
+tsrv_handle_msg({'DOWN', TRef, process, _, _},
+		#tsrv_state{rtab = RTab,
+			    ttab = TTab},
+		Nxt) ->
+    case ets:lookup(RTab, TRef) of
+	[] ->
+	    Nxt;
+	[{Time, TRef} = TKey] ->
+	    ets:delete(RTab, TRef),
+	    ets:delete(TTab, TKey),
+	    case Time =:= Nxt of
+		false ->
+		    Nxt;
+		true ->
+		    case ets:first(TTab) of
+			'$end_of_table' -> infinity;
+			{NextTime, _} -> NextTime
+		    end
+	    end
+    end;
+tsrv_handle_msg({cancel_all_timeouts, BTR, From, Ref},
+		#tsrv_state{rtab = RTab,
+			    ttab = TTab,
+			    btr = BTR},
+		_Nxt) ->
+    tsrv_delete_monitor_objects(RTab),
+    ets:delete_all_objects(TTab),
+    try From ! {canceled_all_timeouts, Ref} catch _:_ -> ok end,
+    infinity;
+tsrv_handle_msg(_GarbageMsg, _StaticState, Nxt) ->
+    Nxt.
+
+tsrv_delete_monitor_objects(RTab) ->
+    case ets:first(RTab) of
+	'$end_of_table' ->
+	    ok;
+	TRef ->
+	    erlang:demonitor(TRef),
+	    ets:delete(RTab, TRef),
+	    tsrv_delete_monitor_objects(RTab)
+    end.
+
+tsrv_handle_timeout(CallTime, #tsrv_state{rtab = RTab,
+					  ttab = TTab} = S) ->
+    case ets:first(TTab) of
+	'$end_of_table' ->
+	    infinity;
+	{Time, _TRef} when Time > CallTime ->
+	    Time;
+	{_Time, TRef} = TKey ->
+	    [{TKey, Proc, Msg}] = ets:lookup(TTab, TKey),
+	    case erlang:is_pid(Proc) of
+		false -> ok;
+		_ -> erlang:demonitor(TRef)
+	    end,
+	    ets:delete(TTab, TKey),
+	    ets:delete(RTab, TRef),
+	    try Proc ! Msg catch _:_ -> ok end,
+	    tsrv_handle_timeout(CallTime, S)
+    end.